PassAndroid/build.gradle

buildscript {

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:0.10.+'
        classpath 'com.jakewharton.sdkmanager:gradle-plugin:0.10.+'
        classpath 'com.stanfy.spoon:spoon-gradle-plugin:0.10.0'
    }
}

apply plugin: 'android-sdk-manager'
apply plugin: 'android'
apply plugin: 'spoon'

repositories {
    mavenCentral()
    maven {
        url project.hasProperty('ligisMavenUrl') ? ligisMavenUrl : "https://raw.github.com/ligi/ligis-mvn-repo/master";
    }
}

android {
    flavorDimensions "maps", "analytics", "distribution"

    productFlavors {

        withMaps {
            flavorDimension "maps"
        }

        noMaps {
            flavorDimension "maps"
        }

        withAnalytics {
            flavorDimension "analytics"
        }

        noAnalytics {
            flavorDimension "analytics"
        }

        forFDroid {
            flavorDimension "distribution"
        }

        forPlay {
            flavorDimension "distribution"
        }
    }

}

dependencies {
    // The Apache Software License, Version 2.0
    compile 'com.googlecode.android-query:android-query:0.25.+'
    compile 'com.google.code.gson:gson:2.2.4'
    compile 'com.android.support:support-v4:19.1.0'
    compile 'net.lingala.zip4j:zip4j:1.3.2'
    compile 'com.android.support:appcompat-v7:19.1.0'
    compile 'com.jakewharton:butterknife:5.1.0'
    compile 'joda-time:joda-time:2.3'
    compile 'com.squareup:otto:1.3.4'

    compile 'org.ligi:AXT:0.28'
    compile 'org.ligi:tracedroid:1.1'
    compile 'com.google.guava:guava:17.0'
    compile 'com.squareup.okhttp:okhttp:1.5.4'
    compile 'fr.nicolaspomepuy:discreetapprate:2.0.1+@aar'

    // cannot use this new version: https://github.com/zxing/zxing/issues/165
    // WARNING: might work on some devices or the emulator - but fails on others
    // compile 'com.google.zxing:core:3.1.0'

    compile fileTree(dir: 'libs', include: 'zxing-core-2.3.0-SNAPSHOT.jar')

    androidTestCompile('com.jakewharton.espresso:espresso:1.1-r3') {
        exclude group: 'com.android.support'
        exclude group: 'com.google.guava'
    }

    androidTestCompile('com.jakewharton.espresso:espresso-support-v4:1.1-r3') {
        exclude group: 'com.android.support'
        exclude group: 'com.google.guava'
    }

    androidTestCompile 'com.squareup.spoon:spoon-client:1.1.0'
    androidTestCompile 'com.squareup:fest-android:1.0.7'

    def play_services = 'com.google.android.gms:play-services:4.3.23'

    withAnalyticsCompile play_services
    withMapsCompile play_services
}


android {
    compileSdkVersion 19
    buildToolsVersion "19.1"

    defaultConfig {
        versionCode 221
        versionName "2.2.1"
        minSdkVersion 9
        targetSdkVersion 19
        packageName "org.ligi.org.ligi.passandroid"
        testInstrumentationRunner "com.google.android.apps.common.testing.testrunner.GoogleInstrumentationTestRunner"

    }

    buildTypes {
        release {
            runProguard false
            proguardFile 'proguard-project.txt'
            applicationVariants.all { variant ->
                def file = variant.outputFile
                variant.outputFile = new File(file.parent, file.name.replace(".apk", "-" + defaultConfig.versionName + ".apk"))
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

    lintOptions {
        abortOnError false
        disable "MissingTranslation"
    }

    // hack for instrumentation testing :-(
    packagingOptions {
        exclude 'LICENSE.txt'
    }


}