wbrawner/SimpleMarkdown
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

Convert .gradle files to gradle.kts

Browse source
This commit is contained in:
William Brawner 2023-01-29 20:41:15 -07:00
parent b9bc147bde
commit 13bfe236a3
Signed by: wbrawner
GPG key ID: 8FF12381C6C90D35
7 changed files with 189 additions and 183 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

145
app/build.gradle
View file

@ -1,145 +0,0 @@
apply plugin: 'com.android.application'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: "com.osacky.fladle"
def keystoreProperties = new Properties()
try {
def keystorePropertiesFile = rootProject.file("keystore.properties")
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
} catch (FileNotFoundException ignored) {
logger.warn("Unable to load keystore properties. Automatic signing won't be available")
keystoreProperties['keyAlias'] = ""
keystoreProperties['keyPassword'] = ""
keystoreProperties['storeFile'] = File.createTempFile("temp", ".tmp").absolutePath
keystoreProperties['storePassword'] = ""
}
android {
packagingOptions {
resources {
excludes += ['META-INF/LICENSE-LGPL-2.1.txt', 'META-INF/LICENSE-LGPL-3.txt', 'META-INF/LICENSE-W3C-TEST', 'META-INF/LICENSE', 'META-INF/DEPENDENCIES']
}
}
configurations.all {
resolutionStrategy.force 'com.google.code.findbugs:jsr305:3.0.1'
}
compileSdkVersion 33
compileOptions {
sourceCompatibility JavaVersion.VERSION_1_8
targetCompatibility JavaVersion.VERSION_1_8
}
kotlinOptions {
jvmTarget = "1.8"
}
defaultConfig {
applicationId "com.wbrawner.simplemarkdown"
minSdkVersion 23
targetSdkVersion 33
versionCode 35
versionName "0.8.13"
testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
testInstrumentationRunnerArguments clearPackageData: 'true'
buildConfigField "boolean", "ENABLE_CUSTOM_CSS", "true"
}
signingConfigs {
playRelease {
keyAlias keystoreProperties['keyAlias']
keyPassword keystoreProperties['keyPassword']
storeFile file(keystoreProperties['storeFile'])
storePassword keystoreProperties['storePassword']
}
}
buildTypes {
debug {
testCoverageEnabled true
}
release {
minifyEnabled true
proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
buildConfigField "boolean", "ENABLE_CUSTOM_CSS", "false"
}
}
flavorDimensions "platform"
productFlavors {
free {
applicationIdSuffix ".free"
versionNameSuffix "-free"
}
play {
signingConfig signingConfigs.playRelease
}
}
testOptions {
unitTests {
includeAndroidResources = true
}
execution 'ANDROIDX_TEST_ORCHESTRATOR'
}
namespace 'com.wbrawner.simplemarkdown'
}
dependencies {
def navigation_version = '2.5.3'
implementation "androidx.navigation:navigation-fragment-ktx:$navigation_version"
implementation "androidx.navigation:navigation-ui-ktx:$navigation_version"
testImplementation 'junit:junit:4.13.2'
testImplementation 'org.robolectric:robolectric:4.2.1'
implementation fileTree(include: ['*.jar'], dir: 'libs')
def espresso_version = '3.5.1'
androidTestImplementation "androidx.test.espresso:espresso-core:$espresso_version"
androidTestImplementation "androidx.test.espresso:espresso-web:$espresso_version"
androidTestImplementation "androidx.test.espresso:espresso-intents:$espresso_version"
androidTestImplementation "androidx.test:runner:1.5.2"
androidTestImplementation "androidx.test:rules:1.5.0"
androidTestUtil "androidx.test:orchestrator:1.4.2"
androidTestImplementation 'androidx.test.ext:junit:1.1.5'
androidTestImplementation 'androidx.test.uiautomator:uiautomator:2.2.0'
implementation 'com.wbrawner.plausible:plausible-android:0.1.0-SNAPSHOT'
implementation 'androidx.appcompat:appcompat:1.6.0'
implementation 'androidx.preference:preference-ktx:1.2.0'
implementation "androidx.fragment:fragment-ktx:1.5.5"
implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
implementation 'com.google.android.material:material:1.8.0'
implementation 'androidx.legacy:legacy-support-v13:1.0.0'
implementation 'com.commonsware.cwac:anddown:0.3.0'
implementation 'com.jakewharton.timber:timber:5.0.1'
playImplementation 'com.android.billingclient:billing:5.1.0'
playImplementation 'com.google.android.play:core-ktx:1.8.1'
playImplementation 'com.google.firebase:firebase-crashlytics:18.3.3'
implementation "androidx.core:core-ktx:1.9.0"
implementation 'androidx.browser:browser:1.4.0'
def coroutines_version = "1.6.4"
implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:$coroutines_version"
def lifecycle_version = "2.2.0"
implementation "androidx.lifecycle:lifecycle-extensions:$lifecycle_version"
kapt "androidx.lifecycle:lifecycle-common-java8:$lifecycle_version"
implementation 'eu.crydee:syllable-counter:4.0.2'
}
android.productFlavors.each { flavor ->
if (getGradle().getStartParameter().getTaskRequests().toString().toLowerCase().contains(flavor.name)
&& flavor.name == 'play') {
apply plugin: 'com.google.gms.google-services'
apply plugin: 'com.google.firebase.crashlytics'
}
}
fladle {
variant = 'playDebug'
useOrchestrator = true
environmentVariables = [
"clearPackageData": "true"
]
testTimeout = "7m"
devices = [
[ "model": "NexusLowRes", "version": "29" ]
]
projectId = 'simplemarkdown'
}
task pullLogFiles(type: Exec) {
commandLine 'adb', 'pull',
'/storage/emulated/0/Android/data/com.wbrawner.simplemarkdown/files/logs'
}

158
app/build.gradle.kts Normal file
View file

@ -0,0 +1,158 @@
import java.io.FileInputStream
import java.io.FileNotFoundException
import java.util.*
plugins {
id("com.android.application")
id("kotlin-android-extensions")
id("kotlin-android")
id("kotlin-kapt")
id("com.osacky.fladle")
}
val keystoreProperties = Properties()
try {
val keystorePropertiesFile = rootProject.file("keystore.properties")
keystoreProperties.load(FileInputStream(keystorePropertiesFile))
} catch (ignored: FileNotFoundException) {
logger.warn("Unable to load keystore properties. Automatic signing won't be available")
keystoreProperties["keyAlias"] = ""
keystoreProperties["keyPassword"] = ""
keystoreProperties["storeFile"] = File.createTempFile("temp", ".tmp").absolutePath
keystoreProperties["storePassword"] = ""
}
android {
packagingOptions {
resources {
excludes += listOf(
"META-INF/LICENSE-LGPL-2.1.txt",
"META-INF/LICENSE-LGPL-3.txt",
"META-INF/LICENSE-W3C-TEST",
"META-INF/LICENSE",
"META-INF/DEPENDENCIES"
)
}
}
compileSdk = 33
compileOptions {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
kotlinOptions {
jvmTarget = "1.8"
}
defaultConfig {
applicationId = "com.wbrawner.simplemarkdown"
minSdk = 23
targetSdk = 33
versionCode = 35
versionName = "0.8.13"
testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
testInstrumentationRunnerArguments["clearPackageData"] = "true"
buildConfigField("boolean", "ENABLE_CUSTOM_CSS", "true")
}
signingConfigs {
create("playRelease") {
keyAlias = keystoreProperties["keyAlias"].toString()
keyPassword = keystoreProperties["keyPassword"].toString()
storeFile = file(keystoreProperties["storeFile"].toString())
storePassword = keystoreProperties["storePassword"].toString()
}
}
buildTypes {
release {
isMinifyEnabled = true
proguardFiles(
getDefaultProguardFile("proguard-android-optimize.txt"),
"proguard-rules.pro"
)
buildConfigField("boolean", "ENABLE_CUSTOM_CSS", "false")
}
}
flavorDimensions.add("platform")
productFlavors {
create("free") {
applicationIdSuffix = ".free"
versionNameSuffix = "-free"
}
create("play") {
signingConfig = signingConfigs["playRelease"]
}
}
testOptions {
unitTests {
isIncludeAndroidResources = true
}
execution = "ANDROIDX_TEST_ORCHESTRATOR"
}
namespace = "com.wbrawner.simplemarkdown"
}
dependencies {
val navigationVersion = "2.5.3"
implementation("androidx.navigation:navigation-fragment-ktx:$navigationVersion")
implementation("androidx.navigation:navigation-ui-ktx:$navigationVersion")
testImplementation("junit:junit:4.13.2")
testImplementation("org.robolectric:robolectric:4.2.1")
val espressoVersion = "3.5.1"
androidTestImplementation("androidx.test.espresso:espresso-core:$espressoVersion")
androidTestImplementation("androidx.test.espresso:espresso-web:$espressoVersion")
androidTestImplementation("androidx.test.espresso:espresso-intents:$espressoVersion")
androidTestImplementation("androidx.test:runner:1.5.2")
androidTestImplementation("androidx.test:rules:1.5.0")
androidTestUtil("androidx.test:orchestrator:1.4.2")
androidTestImplementation("androidx.test.ext:junit:1.1.5")
androidTestImplementation("androidx.test.uiautomator:uiautomator:2.2.0")
implementation("com.wbrawner.plausible:plausible-android:0.1.0-SNAPSHOT")
implementation("androidx.appcompat:appcompat:1.6.0")
implementation("androidx.preference:preference-ktx:1.2.0")
implementation("androidx.fragment:fragment-ktx:1.5.5")
implementation("androidx.constraintlayout:constraintlayout:2.1.4")
implementation("com.google.android.material:material:1.8.0")
implementation("androidx.legacy:legacy-support-v13:1.0.0")
implementation("com.commonsware.cwac:anddown:0.4.0")
implementation("com.jakewharton.timber:timber:5.0.1")
implementation("androidx.core:core-ktx:1.9.0")
implementation("androidx.browser:browser:1.4.0")
val coroutinesVersion = "1.6.4"
implementation("org.jetbrains.kotlinx:kotlinx-coroutines-android:$coroutinesVersion")
val lifecycleVersion = "2.2.0"
implementation("androidx.lifecycle:lifecycle-extensions:$lifecycleVersion")
kapt("androidx.lifecycle:lifecycle-common-java8:$lifecycleVersion")
implementation("eu.crydee:syllable-counter:4.0.2")
}
android.productFlavors.forEach { flavor ->
if (getGradle().getStartParameter().getTaskRequests().toString().toLowerCase()
.contains(flavor.name)
&& flavor.name == "play"
) {
apply(plugin = "com.google.gms.google-services")
apply(plugin = "com.google.firebase.crashlytics")
dependencies {
implementation("com.android.billingclient:billing:5.1.0")
implementation("com.google.android.play:core-ktx:1.8.1")
implementation("com.google.firebase:firebase-crashlytics:18.3.3")
}
}
}
fladle {
variant.set("playDebug")
useOrchestrator.set(true)
environmentVariables.put("clearPackageData", "true")
testTimeout.set("7m")
devices.add(
mapOf("model" to "NexusLowRes", "version" to "29")
)
projectId.set("simplemarkdown")
}
tasks.register<Exec>("pullLogFiles") {
commandLine = listOf(
"adb", "pull",
"/storage/emulated/0/Android/data/com.wbrawner.simplemarkdown/files/logs"
)
}

2
app/proguard-rules.pro vendored
View file

@ -2,7 +2,7 @@
# By default, the flags in this file are appended to flags specified # By default, the flags in this file are appended to flags specified
# in /home/billy/Android/Sdk/tools/proguard/proguard-android.txt # in /home/billy/Android/Sdk/tools/proguard/proguard-android.txt
# You can edit the include path and order by changing the proguardFiles # You can edit the include path and order by changing the proguardFiles
# directive in build.gradle. # directive in build.gradle.kts.
# #
# For more details, see # For more details, see
# http://developer.android.com/guide/developing/tools/proguard.html # http://developer.android.com/guide/developing/tools/proguard.html

36
build.gradle
View file

@ -1,36 +0,0 @@
// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
ext.kotlin_version = '1.7.20'
repositories {
google()
mavenCentral()
maven {url 'https://plugins.gradle.org/m2/' }
}
dependencies {
classpath 'com.android.tools.build:gradle:7.4.0'
classpath 'com.google.gms:google-services:4.3.15'
classpath 'com.google.firebase:firebase-crashlytics-gradle:2.9.2'
classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
classpath "com.osacky.flank.gradle:fladle:0.17.4"
}
}
allprojects {
repositories {
google()
mavenCentral()
maven {
url "https://s3.amazonaws.com/repo.commonsware.com"
}
maven { url 'https://maven.google.com' }
maven {url 'https://plugins.gradle.org/m2/' }
maven {
url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
}
}
}
task clean(type: Delete) {
delete rootProject.buildDir
}

29
build.gradle.kts Normal file
View file

@ -0,0 +1,29 @@
import java.net.URI
buildscript {
repositories {
gradlePluginPortal()
google()
mavenCentral()
}
dependencies {
classpath("com.android.tools.build:gradle:7.4.0")
classpath("com.google.gms:google-services:4.3.15")
classpath("com.google.firebase:firebase-crashlytics-gradle:2.9.2")
classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:1.7.20")
classpath("com.osacky.flank.gradle:fladle:0.17.4")
}
}
allprojects {
repositories {
google()
mavenCentral()
maven {
url = URI("https://s3.amazonaws.com/repo.commonsware.com/")
}
maven {
url = URI("https://s01.oss.sonatype.org/content/repositories/snapshots/")
}
}
}

1
settings.gradle
View file

@ -1 +0,0 @@
include ':app'

1
settings.gradle.kts Normal file
View file

@ -0,0 +1 @@
include(":app")