ansible/packaging/arch/PKGBUILD

#Maintainer: Michel Blanc <mblanc@erasme.org>
pkgname=ansible-git
pkgver=20130430
pkgrel=1
pkgdesc="A radically simple deployment, model-driven configuration management, and command execution framework"
arch=('any')
url="http://ansible.cc"
license=('GPL3')
depends=('python2' 'python2-paramiko' 'python2-jinja' 'python2-yaml')
makedepends=('git' 'asciidoc' 'fakeroot')
conflicts=('ansible')
source=("python-binary.diff")
md5sums=("ab81876d8d4c86c27d137e3d86c25a3a")

_gitroot="https://github.com/ansible/ansible"
_gitname="ansible"

build() {
  cd "$srcdir"
  msg "Connecting to GIT server...."

  if [ -d $_gitname ] ; then
    cd $_gitname && git pull origin
    msg "The local files are updated."
  else
    git clone $_gitroot $_gitname
  fi

  msg "GIT checkout done or server timeout"


  cd "$srcdir/$_gitname"
  patch -p1 -i $srcdir/python-binary.diff
  make
}

package() {
  cd "$srcdir/$_gitname"

  mkdir -p ${pkgdir}/usr/share/ansible
  cp -r ./library/* ${pkgdir}/usr/share/ansible/
  cp -r ./examples ${pkgdir}/usr/share/ansible

  python2 setup.py install -O1 --root=${pkgdir}

  install -D docs/man/man1/ansible.1 ${pkgdir}/usr/share/man/man1/ansible.1
  install -D docs/man/man1/ansible-playbook.1 ${pkgdir}/usr/share/man/man1/ansible-playbook.1
  install -D docs/man/man1/ansible-pull.1 ${pkgdir}/usr/share/man/man1/ansible-pull.1
  install -D docs/man/man1/ansible-doc.1 ${pkgdir}/usr/share/man/man1/ansible-doc.1

  gzip -9 ${pkgdir}/usr/share/man/man1/ansible.1
  gzip -9 ${pkgdir}/usr/share/man/man1/ansible-playbook.1
  gzip -9 ${pkgdir}/usr/share/man/man1/ansible-pull.1
  gzip -9 ${pkgdir}/usr/share/man/man1/ansible-doc.1
}