@Suppress("DSL_SCOPE_VIOLATION")
plugins {
    id(ThunderbirdPlugins.Library.android)
    alias(libs.plugins.kotlin.parcelize)
}

dependencies {
    api(projects.app.ui.base)
    debugImplementation(projects.app.ui.setup)
    implementation(projects.app.core)
    implementation(projects.app.autodiscovery.api)
    implementation(projects.app.autodiscovery.providersxml)
    implementation(projects.mail.common)
    implementation(projects.uiUtils.toolbarBottomSheet)

    // Remove AccountSetupIncoming's dependency on these
    compileOnly(projects.mail.protocols.imap)
    compileOnly(projects.mail.protocols.webdav)

    implementation(projects.plugins.openpgpApiLib.openpgpApi)

    implementation(libs.androidx.appcompat)
    implementation(libs.androidx.preference)
    implementation(libs.preferencex)
    implementation(libs.preferencex.datetimepicker)
    implementation(libs.preferencex.colorpicker)
    implementation(libs.androidx.recyclerview)
    implementation(projects.uiUtils.linearLayoutManager)
    implementation(projects.uiUtils.itemTouchHelper)
    implementation(libs.androidx.lifecycle.runtime.ktx)
    implementation(libs.androidx.lifecycle.viewmodel.ktx)
    implementation(libs.androidx.lifecycle.livedata.ktx)
    implementation(libs.androidx.constraintlayout)
    implementation(libs.androidx.localbroadcastmanager)
    implementation(libs.androidx.swiperefreshlayout)
    implementation(libs.ckchangelog.core)
    implementation(libs.tokenautocomplete)
    implementation(libs.safeContentResolver)
    implementation(libs.materialdrawer)
    implementation(libs.searchPreference)
    implementation(libs.fastadapter)
    implementation(libs.fastadapter.extensions.drag)
    implementation(libs.fastadapter.extensions.utils)
    implementation(libs.circleimageview)
    api(libs.appauth)

    implementation(libs.commons.io)
    implementation(libs.androidx.core.ktx)
    implementation(libs.jcip.annotations)
    implementation(libs.timber)
    implementation(libs.mime4j.core)
    implementation(libs.kotlinx.coroutines.core)
    implementation(libs.kotlinx.coroutines.android)

    implementation(libs.glide)
    annotationProcessor(libs.glide.compiler)

    testImplementation(libs.bundles.shared.jvm.test.legacy)
    testImplementation(projects.core.testing)
    testImplementation(projects.mail.testing)
    testImplementation(projects.app.storage)
    testImplementation(projects.app.testing)
    testImplementation(libs.robolectric)
    testImplementation(libs.androidx.test.core)
    testImplementation(libs.kotlin.test)
    testImplementation(libs.kotlinx.coroutines.test)
    testImplementation(libs.turbine)
}

android {
    namespace = "com.fsck.k9.ui"

    buildFeatures {
        buildConfig = true
    }

    buildTypes {
        debug {
            val useNewSetupUi = if (project.hasProperty("k9mail.useNewSetupUi")) {
                project.property("k9mail.useNewSetupUi").toString()
            } else {
                "false"
            }
            buildConfigField("boolean", "USE_NEW_SETUP_UI_FOR_ONBOARDING", useNewSetupUi)

            manifestPlaceholders["appAuthRedirectScheme"] = "FIXME: override this in your app project"
        }
        release {
            buildConfigField("boolean", "USE_NEW_SETUP_UI_FOR_ONBOARDING", "false")

            manifestPlaceholders["appAuthRedirectScheme"] = "FIXME: override this in your app project"
        }
    }
}