ansible/packaging/arch/PKGBUILD

# Maintainer: Michel Blanc <mblanc@erasme.org>

pkgname=ansible-git
pkgver=1.1.4095.g3f2f5fe
pkgrel=1
pkgdesc='Radically simple IT automation platform'
arch=('any')
url='http://www.ansible.com'
license=('GPL3')
depends=('python2' 'python2-paramiko' 'python2-jinja' 'python2-yaml')
makedepends=('git' 'asciidoc' 'fakeroot')
optdepends=('python2-pyasn1: needed for accelerated mode'
            'python2-crypto: needed for accelerated mode'
            'python2-keyczar: needed for accelerated mode')
conflicts=('ansible')
provides=('ansible')
backup=('etc/ansible/ansible.cfg')
source=($pkgname::git://github.com/ansible/ansible.git)
md5sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --long | sed 's/^v//;s/-/./g'
}

build() {
  cd $pkgname
  make PYTHON=python2
}

package() {
  cd $pkgname

  install -dm755 $pkgdir/usr/share/ansible
  cp -dpr --no-preserve=ownership ./library/* "$pkgdir/usr/share/ansible/"
  cp -dpr --no-preserve=ownership ./examples "$pkgdir/usr/share/ansible"

  python2 setup.py install -O1 --root="$pkgdir"

  install -Dm644 examples/ansible.cfg $pkgdir/etc/ansible/ansible.cfg

  install -Dm644 README.md $pkgdir/usr/share/doc/ansible/README.md
  install -Dm644 COPYING $pkgdir/usr/share/doc/ansible/COPYING
  install -Dm644 CHANGELOG.md $pkgdir/usr/share/doc/ansible/CHANGELOG.md

  install -dm755 ${pkgdir}/usr/share/man/man{1,3}
  cp -dpr --no-preserve=ownership docs/man/man1/*.1 "$pkgdir/usr/share/man/man1"
  cp -dpr --no-preserve=ownership docs/man/man3/*.3 "$pkgdir/usr/share/man/man3"
}